ANSYS经典界面知识一箩筐（9）：移动热源
本文摘要（由AI生成）：
本文介绍了移动热源-圆柱形/方形的APDL/命令流操作方法。首先通过GUI操作，然后输出lgw命令流文件，然后do命令写入命令流文件，然后batch或者界面读入lgw文件求解。在GUI操作中，单元为70，密度7850、48传导、480比热，模型为圆柱体，半径0.1，厚度0.04，切割为4个体，网格线分段36、10、5或者加密一级，分析类型为瞬态热、full，一致初始温度20，对流为所有面对流系数20环境温度20，修改坐标系为圆柱坐标系。在命令流解释中，首先清除网格，然后对4个体中的一个划分网格，进入求解器，进行瞬态分析，full算法，lump选项默认off，对流施加到所有面上，对流系数及环境温度均为20。最后，在圆柱坐标系下，清理节点的所有载荷，设置时间间隔和子步数，选择Z坐标为h的节点。
移动热源-圆柱形/方形（APDL/命令流）
1、项目描述：
先通过GUI操作，然后输出lgw命令流文件，然后do命令写入命令流文件，然后batch或者界面读入lgw文件求解。
GUI：
单元70
材料密度7850、48传导、480比热
模型：圆柱体，半径0.1，厚度0.04，切割为4个体
网格：线分段36、10、5或者加密一级；
分析类型：瞬态热、full
一致初始温度20
对流：所有面对流系数20环境温度20
修改坐标系为圆柱坐标系；
【CSYS,1 】
写出lgw文件；
添加do命令流；
【*do,n,1,10,1
*do,i,1,36,1
BFDELE,all,HGEN
TIME,I+360/10*(n-1)
NSUBST,4,4,4
NSEL,S,LOC,Z,0.04
NSEL,R,LOC,Y,10*(i-1),10*i
NSEL,R,LOC,X,0.01*(n-1),0.01*n
BF,all,HGEN,1e9
nplot
alls
solve
*enddo
*enddo】
Batch或者GUI界面读入dgw文件求解；
后处理；
2、圆柱形移动热源，命令流解释如下(红色为必须命令流，其他为可GUI操作)：
finish
/clear
!模型参数
!model
r=0.1 !圆柱体半径
h=0.04 !圆柱体厚度
hjkd=0.01 !选择X坐标对应节点时使用的常数
!************
v=10
rg=1e9 !热生成功率
hanjiequanshu=10 !线分段数
!function
wgds=36 !线分段数
jxwgs=r/hjkd !=10
jgsj=10/v !=1
chengshu=5 !线分段数
!*
!前处理
/prep7
! 单元
ET,1,SOLID70
!材料
MPTEMP,,,,,,,,
MPTEMP,1,0 !只有一个温度
MPDATA,DENS,1,,7850 !密度
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,C,1,,480 !比热
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,1,,48 !热传导率
NUMCMP,ALL !Compresses 压缩所有的numbering
!模型
CYL4, , ,r, , , ,h !创建圆面/圆柱体.
!CYL4, XCENTER, YCENTER, RAD1内半径, THETA1, RAD2外半径, THETA2, DEPTH厚度
!*
!坐标平面planr旋转、切割体
wpro,,,30.000000 !绕Y轴旋转30°
wpro,,,30.000000
wpro,,,30.000000 !3次共旋转90°，其实可以一次完成
VSBW,all !用工作平面切割体（为了更好划分网格）
wpro,,30.000000, !再选择工作平面
wpro,,30.000000,
wpro,,30.000000,
VSBW, all !再切割体
!*
!线操作、选择、分段等
FLST,5,8,4,ORDE,4 ! 线操作（一般GUI操作，会生成此命令）
FITEM,5,15 !Identifies items chosen by a picking operation (GUI).
FITEM,5,-18
FITEM,5,20
FITEM,5,-23
CM,_Y,LINE !线操作
LSEL, , , ,P51X !选择上下顶面的8条线
CM,_Y1,LINE
CMSEL,,_Y !创建组元？
!*
LESIZE,_Y1, , ,jxwgs, , , , ,0 !对上面选择的8条线进行10段分段(为了更精确分析，网格可以再加密一级，不影响循环，因为循环是通过坐标值去选择节点的)
!*
FLST,5,5,4,ORDE,5
FITEM,5,9
FITEM,5,-10
FITEM,5,13
FITEM,5,-14
FITEM,5,19
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
!*
LESIZE,_Y1, , ,chengshu, , , , ,0 !对上面选择的5条线进行5段分段
!*
FLST,5,8,4,ORDE,2
FITEM,5,1
FITEM,5,-8
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
!*
LESIZE,_Y1, , ,wgds, , , , ,0 !对上面选择的8条圆弧线进行36段分段(为了更精确分析，网格可以再加密一级)
!*
!*
!体网格划分
VCLEAR,4 !清除网格
VSWEEP,4,3,16 !对4个体中的一个划分网格
!*
!*
VSWEEP,6,16,19 !对4个体中的一个划分网格
!*
!*
VSWEEP,5,19,4 !对4个体中的一个划分网格
!*
!*
VSWEEP,1,4,3 !对4个体中的一个划分网格
!*
!进入求解器
/solu
ANTYPE,4 !瞬态分析
TRNOPT,FULL !full算法
LUMPM,0 !lump选项默认off
TUNIF,20, !uniform temperature（20℃） to all nodes
ASEL,S,EXT !选择面，S为选择一个新的，EXT为外部面
!对流
SFA,all,1,CONV,20,20 !对流施加到所有面上，对流系数及环境温度均为20
!*
!下面命令流必须APDL输入(加载及循环)
!圆柱坐标系
CSYS,1 !坐标系1（系统自带的圆柱坐标系）（GUI如下图）
*do,n,1,hanjiequanshu,1
*do,i,1,36,1
BFDELE,all,HGEN
!先清理节点的所有载荷（GUI不需要）
TIME,jgsj*I+360/v*(n-1)
!时间（间隔1秒，通过360*10次循环，计算到360秒），时间分别为1……36（n=1）、1+36……36+36（n=2）、、、1+36*2……36*36*2（n=3）……1+36*9……36+36*9（n=10）
NSUBST,4,4,4
!初始子步数、最大子步数、最小子步数（每1秒4个子步）
NSEL,S,LOC,Z,h
!节点选择，s选择一个新的，loc为通过坐标系选择，Z为Z轴，h为0.04（选择Z=0.04面上的所有节点）
NSEL,R,LOC,Y,10*(i-1),10*i
!进一步通过Y坐标选择节点（reselect）（选择Y值从0-10【i=1时】、10-20【i=2】、、、350-360【i=36时】的节点）
NSEL,R,LOC,X,hjkd*(n-1),hjkd*n
!进一步通过X坐标选择节点（reselect）（选择X值从0-0.01【n=1时】、0.01-0.02【n=2】、、0.09-0.1【n=10】）（hjkd可不用定义参数，直接用0.01即可）
BF,all,HGEN,rg !施加热载荷，all所有上面选取的节点，HGEN为热生成功率，rg为前边定义的参数1e9（当然也可以不用定义此参数，直接这里输入1e9即可）
Nplot !节点显示
Alls !应该为“allsel”
Solve !求解
*enddo
*enddo
FINISH
!后处理
/POST1
!*
EFACET,1
PLNSOL,TEMP,,O
3 、结果查看
